Возможно, слетели настройки BIOS (вернулись к дефолтным), обычно тогда при загрузке сразу выбрасывает в BIOS, если не выбрасывает, а появляется синий экран, на котором ругаются на ACPI: «The BIOS in this system is not fully ACPI compilant», и, возможно ошибка с кодом STOP:000000A5 то в BIOS надо зайти и проверить:

1. Security --> Secure boot menu --> Secure boot установить в Disable, сохранить (F10), перезагрузиться, войти в BIOS опять.
2. Boot --> Launch CSM выставить в Enabled. Cохранить (F10), перезагрузиться, войти в BIOS опять.
3. Advancend --> OS Selection выставить в Windows 7. Cохранить (F10), перезагрузиться.

Пример синего экрана:

1. Shred для Windows (копия)
2. Устранил финальный недостаток SHRED под Windows в BAT-файле (копия)
3. Random Renamer (копия)

В [2] описал недостаток утилиты shred, а именно: затирая файл она никак не меняет его имени, потому, если вы shred‘ом удалили файл, например, с именем Путин бомба взрыв чеченцы.doc, содержимое файла затрется, а название останется.

Впрочем, там же описал недостаток и получения случайного имени файла стандартными средствами BAT/CMD: Имя временного файла весьма характерное, при анализе диска будет видно, что кто-то скриптом пользовался. Как сделать нормальные случайные имена файлов в CMD (вида lfcx16.tmp, например) без внешних утилит, я пока не понял.

Впрочем, да, без PowerShell или JS/VBS стандартными средствами CMD/BAT получить нормальное случайное имя файла сложно, так что написал простенькую утилиту Random Renamer [3], которую, впрочем, писал немного для другого, но в [3] обещал пример, как ее можно использовать со shred в BAT-файле.

1. Отключаем режим вывода команд:

@echo off

2. Проверяем, чтобы в первом параметре BAT-файла были указаны маска или имя файла, иначе насерет в консоль ошибками и будет некрасиво:

IF "%1" EQU "" goto paramerr

3. В конце BAT-файла дописываем метку :paramerr и вывод сообщения об ошибке:

:paramerr
echo First parameter must be file name or file mask!
echo e.g. rrshred.bat *.txt
echo e.g. rrshred.bat text.txt

4. Генерируем имя для списка файлов, которые будут переименованы и обработаны shred:

set RLST=%TEMP%\%RANDOM%.%RANDOM%

5. Переименовываем файлы в текущем каталоге Random Renamer’ом и отправляем вывод RR в список файлов:

rr -m %1 -v >%RLST%

где:
-m %1 — задание маски переименуемых файлов
-v — включить вывод процесса переименования

Вывод производится на STDOUT, потому перенаправляем его во временный файл (>%RLST%).

Пример содержимого файла (X:\Temp\15158.18655):

Rename files...
Z:\Test1.txt --> 1.txt --> tuz3v4t3.ovw OK.
Z:\Test2.txt --> 2.txt --> npk5b7jn.q12 OK.
Z:\Test3.txt --> 3.txt --> sqtn63cl.dwa OK.
Z:\Test4.txt --> 4.txt --> m371e448.q12 OK.

Found files: 4
Renamed files: 4
Error files: 0

6. В цикле вытаскиваем имена переименованных файлов из файла-списка:

FOR /F "tokens=5,5 delims= " %%i in (%RLST%) do (

	[внутри цикла]

)

Справка по команде FOR BAT-файла (копия в PDF)

Внутри цикла:

1. Вызываем shred для каждого файла из списка:

shred -n 3 -z %%i

где:

-n 3 — затереть случайными данными файл в 3 прохода
-z — сделать дополнительный проход, затерев содержимое файла нолями (символом с кодом 0x00h)

2. Удаляем файл:

del %%i

После цикла затираем и удаляем сам файл со списком файлов, имя которого в %RLST%:

shred -n 3 -z %RLST%
del %RLST%
exit /b

Команда exit /b завершает работу BAT-файла, параметр /b указывает, чтобы по выходу из BAT-файла, командный процессор не был бы закрыт.

Ниже в BAT-файле будет идти метка :paramerr

@echo off

IF "%1" EQU "" goto paramerr

SET RLST=%TEMP%\%RANDOM%.%RANDOM%

rr -m %1 -v >%RLST%

FOR /F "tokens=5,5 delims= " %%i in (%RLST%) do (

	shred -n 3 -z %%i
	del %%i

)

::remove list of files
shred -n 3 -z %RLST%
del %RLST%
exit /b

:paramerr
echo First parameter must be file name or file mask!
echo e.g. rrshred.bat *.txt
echo e.g. rrshred.bat text.txt

На GitHub

Понадобилось в одном из офисов массово обновить винды.

1. Теперь пакет с сайта не скачать с российских IP.
2. Не установится, если обнаружит российский IP при запуске, надо физически отключать интернеты, выдернув сетевой кабель из компа.

Понятно, в связи с чем.

На форумах (дурацких) люди (дурацкие) говорят, что последний пакет обновлений грохает русскую винду, даже если предыдущие и следующие условия соблюдены. Все работает, проблем не возникло, проверено 15 раз.

Как ответить на вопросы правильно, думаю, догадаетесь сами.
И да, минутку надо подождать, после появления второго окна (на совсем медленных ведрах лучше две).

Скачать обновление (последняя версия)

Последняя довоенная версия (копия), если кому надо для успокоения души. Ключик спрашивать лично в Телеграме, вате не дам.

Про shred в версии под винды, рассказывал здесь (копия)

И рассказал там про фатальный недостаток утилиты, затирая и удаляя файл она никак не меняет его имени, потому, если вы shred‘ом удалили файл, например, с именем Путин бомба взрыв чеченцы.doc, содержимое файла затрется, а название останется. Сделал обертку в виде BAT-файла, чтобы сей недостаток устранить:

Самый простой способ, это просто использовать переменную %RANDOM%, например, в таком виде:

%TEMP%\%RANDOM%.%RANDOM%

Вариант сгенерированного имени:

C:\Windows\Temp\20422.19028

1. Генерируем имя для списка файлов, обработанных shred:

set RLST=%TEMP%\%RANDOM%.%RANDOM%

По-хорошему надо бы проверить, существует ли такой файл, если существует, сгенерировать новое имя, но тут это единственное имя файла, которое может попасть на существующий файл — в общем, я забил на это.

2. Вызываем shred:

shred -n 3 -z -v %1 2>%RLST%

где:

-n 3 — количество проходов для затирания содержимого файла
-z — дополнительный проход, содержимое файла затирается нолями (символом с кодом 0)
-v — режим подробного вывода на консоль, он пойдет в файл, там будут имена затертых файлов, они понадобятся далее.
2> shred выводит данные на STDERR — перенаправляем вывод в файл, чье имя содержится в переменной %RLST%.

Содержимое файла из переменной %RLST%:

>rshred.bat *.txt

shred: 1.txt: pass 1/4 (random)...
shred: 1.txt: pass 2/4 (random)...
shred: 1.txt: pass 3/4 (random)...
shred: 1.txt: pass 4/4 (000000)...
shred: 2.txt: pass 1/4 (random)...
shred: 2.txt: pass 2/4 (random)...
shred: 2.txt: pass 3/4 (random)...
shred: 2.txt: pass 4/4 (000000)...
shred: 3.txt: pass 1/4 (random)...
shred: 3.txt: pass 2/4 (random)...
shred: 3.txt: pass 3/4 (random)...
shred: 3.txt: pass 4/4 (000000)...
shred: readme.txt: pass 1/4 (random)...
shred: readme.txt: pass 2/4 (random)...
shred: readme.txt: pass 3/4 (random)...
shred: readme.txt: pass 4/4 (000000)...

В цикле вытаскиваем из временного файла (%RLIST%):

FOR /F "tokens=2,5 delims=: " %%i in (%RLST%) do (
	[в цикле]
)

Справка по команде FOR BAT-файла (копия в PDF)

3. В выводе имя файла повторяется несколько раз, потому будем искать строчку, где файл упоминается последний раз ((000000)):

IF "%%j" EQU "(000000)..." (
		[ниже код после проверки]
	)

4. Получаем временное имя файла:

set TMPNAME=%RANDOM%.%RANDOM%

5. Переименовываем обработанный файл в случайное имя, полученное выше:

ren %%i !TMPNAME!

6. Удаляем переименованный файл:

del !TMPNAME!

7. После цикла отключаем установку локальных параметров:

Setlocal DisableDelayedExpansion

Справка по команде (копия в PDF)

8. Затираем и удаляем сам файл с логом из %RLST%:

::remove list of files
shred -n 3 -z %RLST%
del %RLST%

Минус скрипта, который даже плюс:
У группы удаляемых файлов в цикле будет одно и то же имя файла, из-за хреновой работы %RANDOM% в CMD (копия), но почему это минус, который плюс — при анализе диска не будет видно, сколько именно файлов было удалено (проверено в WinHex).

Минус скрипта, который минус:
Имя временного файла весьма характерное, при анализе диска будет видно, что кто-то скриптом пользовался. Как сделать нормальные случайные имена файлов в CMD (вида lfcx16.tmp, например) без внешних утилит, я пока не понял, опять же, из-за косячного %RANDOM% в винде.

На GitHub

Продолжение. Начало здесь (копия)

Распишу алгоритм, реализованный в функции:

1. Устанавливаем режимы работы:

SetLocal EnableExtensions EnableDelayedExpansion

Справка по команде Копия в PDF

2. Устанавливаем начальные переменные в функции:

Set Out=%~0

Записываем в локальную переменную имя функции (%~0). Зачем? А спросите у дизайнеров языка CMD, он ебанутый, и без этой фишки вывод данных из функции не сработает.

Set "param=%~1"

Записываем первый и единственный параметр переданный функции (%~1), т.е. строку, в локальную переменную param.

Set "str=A!param!"

Добавляем символ A к строке param с начала строки, сохраняем результат в локальную переменную str. На самом деле, можно добавить любой печатный латинский символ. Пусть будет A.

Set "len=0"

Счетчик длины устанавливаем в ноль.

3. Запускаем основной цикл:

for /l %%a in (30,-1,0) do (
	[см. далее]
)

Второй параметр цикла (-1) означает, что цикл пойдет в обратном порядке, от 30 до 0.

4. Внутри цикла:

4.1. set /a "len|=1<<%%a"
Производится битовый сдвиг переменной цикла (%%a), т.е. к единице (двоичной) добавляется %%a нолей (двоичных).

4.2. Над полученным числом производится операция побитового ИЛИ (|), результат записывается в переменную len.

4.3. Запускается второй (внутренний) цикл, количество итераций которого проводится по полученной ранее длине (len):

for %%b in (!len!) do [...]

4.3.1. if "!str:~%%b,1!"==""

Внутри второго цикла, если мы нашли пустой символ на позиции, которую указывает счетчик (%%b), проводим битовые операции над длиной:

4.3.2. set /a "len&=~1<<%%a"

4.3.2.1. Сначала проводится битовый сдвиг с единицей на %%a разрядов (нолей)
4.3.2.2. Полученные биты инвертируются (~) т.е., например, если полученное значение было равно 1000 (в двоичной системе счисления), то после операции ~ оно превращается в 0111.
4.3.2.3. Последней производится операция побитового И (&) и значение присваивается переменной len.

5. Функция возвращает результат:

endlocal & set %Out:~1%=%len%

Функция целиком:

::Start Strlen function
:Strlen 
	SetLocal EnableExtensions EnableDelayedExpansion
	Set Out=%~0
	Set "param=%~1"
	Set "str=A!param!"
	echo %str%
	Set "len=0"
        for /l %%a in (30,-1,0) do (
        	set /a "len|=1<<%%a"
				
        	for %%b in (!len!) do if "!str:~%%b,1!"=="" set /a "len&=~1<<%%a"
    )
endlocal & set %Out:~1%=%len%
exit /b 0

Сделал разбор алгоритма по шагам, при меньшем числе итераций (установил в основном цикле первый параметр равным 4 и строку для измерения длины сделал 10 символов — 0123456789). Все свел в таблицу:

Посмотреть разбор алгоритма по шагам (PDF)

Пример на GitHub

Определение длины строки штатными средствами CMD/BAT тот еще геморрой, но понадобилось, потому расскажу про несколько способов. В этом выпуске самый простой.

Команда set: экспериментально 1024 символа.

Общий размер переменной: 8191 символ.
Длина командной строки: 8191 символ.
Отсюда

Внимание! Совместимость алгоритмов от Windows XP и выше. Т.е. для DOS и Windows 9x не подойдет.

Есть медленное, но простое решение «в лоб»:

1. Задать циклу for перебирать числа от 0 до какого-нибудь заведомо большого числа, например 9000.

for /L %%a in (0,1,9000) do […]

2. Получать из строки символ под номером %%a:

param:~%%a,1

В общем виде:
param:a,b
где:
param: — взять из переменной param символ(ы)
a — позиция нужного символа
b — количество символов

3. Сравнивать его с пустой строкой, и если строка не пуста (NEQ):

if "!param:~%%a,1!" NEQ "" ( […]

4. Прибавить счетчик символов в отдельной переменной:

Set /a "len+=1"

Иначе прервать цикл.

Можно реализовать это в виде функции BAT-файла:

:Strlen 
	SetLocal EnableExtensions EnableDelayedExpansion
	Set Out=%~0
	Set "param=%~1"
	Set "len=0"

	for /L %%a in (0,1,9000) do (
			if "!param:~%%a,1!" NEQ "" (
				Set /a "len+=1"
			) else goto :_break
		)
	:_break

Пример BAT-файла на GitHub

Вывод на экран для строк:

Set "String1=ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789"
Set "String2=132 sd72 362 232 83827 3n238237"
Set "String3=1 >>>32 lnsdfn lskd &&&&&     _----__\\\\|||sd72 *&&&@@######~~~~~362 232 83827 3n238237"
Set "String4=A"
Set "String5=%%1"

Последняя строка задается в качестве параметра командной строки BAT-файла.

>strlenslow.bat 7894561230.

Length String 1 - [62]
Length String 2 - [31]
Length String 3 - [88]
Length String 4 - [1]
Length String 5 (Command Line Parameter) - [11]

Проблемы алгоритма:

1. Медленный
2. Если задать пустую строку в параметре командной строки — алгоритм ломается:

>strlenslow.bat
[...]
Length String 5 (Command Line Parameter) - [9001]

Хотя, последнее легко исправить.

А про более быстрый алгоритм поговорим в следующей серии.